Regelmässige Verben

[ Weiter ] [ Seitenende ] [ Überkapitel ] [ Bitte Skript-Fehler melden ]

6.1. Regelmässige Verben

Komponente 1: Stämme ▸▸▸

define Stems [ {lach}|{rede}|{mal}|{zeig}|{laus} ];

pict

Was fällt auf bei den Stämmen?

Komponente 2: Deﬁnition der lexikalischen Grammatik
Welche Werte sind für welche Merkmale erlaubt? Welche Symbole grenzen Stamminformation, Werte von Merkmale und mehrere Merkmalwertpaare voneinander ab?

define Per1 [ Per ":" 1 ];
define Per2 [ Per ":" 2 ];
define Per3 [ Per ":" 3 ];

define Person [ Per1|Per2|Per3 ];
define Number [ Num ":" [Sg|Pl] ];
define Tense [ Tns ":" [Past|Pres] ];

define Features [ Person " " Number " " Tense ];

define VerbLex [ Stems "," Features ];

Könnte man Person nicht einfacher deﬁnieren?

Komponente 3: Regel für Imperfekt
Hänge ein te (an den Stamm), falls das Merkmal Tns den Wert Past hat. Beispiel: sag → sag-te- ; rede → rede-te- ; laus → laus-te-

#Rule Block 1
define R101 [ [..] -> {te} || _ "," [$[Tns":"Past]] ] ;
define RB1 [R101];

Warum wird [..] verwendet und nicht 0?
Wird hier “an den Stamm” angehängt?
Wieviele Merkmalwertpaare Tns":"Past dürfen bzw. können überhaupt links oder rechts vom Kontext vorkommen?

Transduktor für Imperfektregel

pict

Komponente 3: Regeln für Personalendungen
Hänge diejenige Personalendung an, welche der Merkmalsspeziﬁkation von Person und Numerus entspricht!

Beispiel: sag → sag-st ; rede-te → rede-te-n

#Rule Block 2 - Person/Number
define R201 [ [..] -> {e}  || _ "," [$[Per ":" 1 " " Num ":" Sg]] ] ;
define R202 [ [..] -> {st} || _ "," [$[Per ":" 2 " " Num ":" Sg]] ] ;
define R203 [ [..] -> {t}  || _ "," [$[Per ":" 3 " " Num ":" Sg]] ] ;
define R204 [ [..] -> {en} || _ "," [$[Per ":" 1 " " Num ":" Pl]] ] ;
define R205 [ [..] -> {t}  || _ "," [$[Per ":" 2 " " Num ":" Pl]] ] ;
define R206 [ [..] -> {en} || _ "," [$[Per ":" 3 " " Num ":" Pl]] ] ;

define RB2 [ R201 .o. R202 .o. R203 .o. R204 .o. R205 .o. R206 ];

Wieviele Zustände hat wohl RB2?
Könnte man dasselbe mit weniger Regeln oder kürzer schreiben?
Werden nur zulässige Formen erzeugt damit?

Komponente 4: Korrektur von Übergeneralisierung

# Im Imperfekt hat 3. Person kein -t am Wortende.
define M01 [ {tet} -> {te} || _ [$[Per":"3" "Num":"Sg" "Tns":"Past]] ] ;

# In Stämmen mit e am Schluss fällt das e in der Personalendung weg.
define M02 [ {ee} -> {e} ];

define MP [ M01 .o. M02 ];

Beispiel: rede-et; mal-te-t

Was passiert, wenn man Stämme wie beehr oder bet nimmt?

Vor-Montage: Zusammenfügen von Stämmen und Regeln

# Verbtransduktor mit lexikalischer Information auf Wortformebene
define VerbNC [ VerbLex .o. RB1 .o. RB2 .o. MP ];

xfst[0]: read regex VerbNC ;
xfst[1]: random-lower 5
zeigten,Per:3 Num:Pl Tns:Past
lachen,Per:3 Num:Pl Tns:Pres
lachtest,Per:2 Num:Sg Tns:Past
hoffen,Per:1 Num:Pl Tns:Pres
zeigte,Per:1 Num:Sg Tns:Past

Die untere Sprache enthält nebst den Wortformen noch alle morphologischen Merkmale!
Wie können wir alles ausser den Wortformen entfernen?

Komponente 5: Wortformen ausﬁltern

# Zulässige Zeichen auf der Wortformen-Ebene

define L [ a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p|q|r|s|t|u|v|w|x|y|z|ä|ö|ü|ß ];

#
define Cleanup [ \L -> 0 ];

# Bereinige die untere Sprache des Transduktors!
define Verb [ VerbNC .o. Cleanup ];

Was macht der Transduktor namens cleanup (in Prosa ausgedeutscht)?
Warum hat man die morphologischen Merkmale überhaupt auf der unteren Sprache gehabt?
Sind alle erzeugten Wortformen korrekt?

[ Weiter ] [ Seitenbeginn ] [ Überkapitel ] [ Bitte Skript-Fehler melden ]