Adjektive

[ Weiter ] [ Zurück ] [ Zurück (Seitenende) ] [ Seitenende ] [ Überkapitel ] [ Bitte Skript-Fehler melden ]

8.2. Adjektive

8.2.1. Lexikalische Grammatik

Lexikalische Grammatik: Werte ▸▸▸
Inhalt der Datei "infl/adjective_proto_paradigm.xfst"

Lexikalische Grammatik: Merkmalwertpaare

define AdjPosPairs ["&pos" AdjPosValues];
define AdjTypePairs ["&type" AdjTypeValues];
define AdjUsePairs ["&use" AdjUseValues];
define AdjInflexionPairs ["&inflexion" AdjInflexionValues];
define AdjNumbPairs ["&numb" AdjNumbValues];
define AdjGendPairs ["&gend" AdjGendValues];
define AdjDegrPairs ["&degr" AdjDegrValues];
define AdjCasePairs ["&case" AdjCaseValues];
define AdjInflectPairs ["&inflect" AdjInflectValues];

! Kanonische Reihenfolge der Paare
define AdjPairs [ AdjPosPairs AdjTypePairs AdjUsePairs
AdjInflexionPairs AdjNumbPairs AdjGendPairs
AdjDegrPairs AdjCasePairs AdjInflectPairs
];

Lexikalische Grammatik: Übergeneralisierendes Schema

define AdjectiveProtoParadigm [
 [
 [\ AdjValuesAndFeatures]+
 & [$. "<CLASS>"]
 & [$. "</CLASS>"]
 ] AdjPairs
];

Prototypische Charakterisierung aus Eﬃzienzgründen

Eine Eingrenzung aller möglicher Zeichenketten auf der lexikalischen Seite hilft mit, die ET aus komponierten Regeln vernünftig gross zu halten.

Ohne die beiden Einschränkungen mit "<CLASS>" bzw. "</CLASS>" hat beispielsweise der Transduktor für die Adjektiv-Klasse 145 von “bang” die Grösse 2.2 Mb. 5106 states, 176646 arcs statt 220.4 Kb. 658 states, 17444 arcs.

8.2.2. Flexion

Klassenbasierte Flexion der Adjektive ▸▸▸

Klasseninformation ∙Lemmata ∙Proto-Flexionsparadigma

∘

Generelle Restriktionen und klassenspeziﬁsche Ersetzungsregeln

[ "<CLASS>" "<OLIFC.533/>" "</CLASS>"
@stxt"lemma/adjective/OLIF533.slex" AdjectiveProtoInflParadigm
]
.o.
AdjectiveRule533
|...

Übergenerierendes Proto-Flexionsparadigma ▸▸▸

Übergenerierendes Proto-Flexionsparadigma

Eigenschaften

Abstrakte Archi-Morpheme für die Steigerung werden als Platzhalter eingeführt:
[""|"<COMP/>"|"<POS/>"]
Die Steigerung wird als Flexionsphänomen betrachtet, das auf der lexikalischen Seite letztlich nur durch die morphosyntaktischen Merkmale "&degr" ["=pos"|"=comp"|"=sup"] repräsentiert wird.
An der Grenze "<DEGR/>" spielen sich die meisten morpho-phonetischen Alternationen ab wie E-Tilgung oder -Einfügung.
Die Grenze "<AINFL/>", welche die Flexionsendungen im engen Sinn abtrennt, ist interessanterweise morphologisch uninteressant.

8.2.3. Restriktionen und Ersetzungsregeln

Klassenspeziﬁsche Regeln ▸▸▸

Allgemeine Restriktionen (AdjectiveRestr) reduzieren die Übergenerierung der lexikalischen Grammatik: z.B. kein Genus im Plural.
AdjectiveDegrRule setzt die Archi-Morpheme der Steigerung graphematisch um: z.B. "" zu st.
Für jede OLIF-Klasse wird automatisch aus der linguistischen Beschreibung eine Gesamtregel erzeugt.
Die Merkmale A bis L speziﬁzieren bestimmte Ersetzungsvorgänge. (Wert 0 ist neutral.)

define AdjectiveRule533 [ AdjectiveRestr
   .o. AdjectiveRuleA0 .o. AdjectiveRuleB0 .o. AdjectiveRuleC0 .o. AdjectiveRuleD5
   .o. AdjectiveRuleE0 .o. AdjectiveRuleF0 .o. AdjectiveRuleG0 .o. AdjectiveRuleH0
   .o. AdjectiveRuleI0 .o. AdjectiveRuleJ0 .o. AdjectiveRuleK0 .o. AdjectiveRuleL0
   .o.  AdjectiveDegrRule ];

Linguistische Beschreibung ▸▸▸
Die OLIF-Klassen werden auf Grund ihrer lexikalischen, morphologischen und morpho-phonetischen Eigenschaften charakterisiert. ▸▸▸

Flektierbarkeit : A0=Flektierbar A1=Nicht ﬂektierbar
E-Tilgung im Komparativ bei er, en: F0=Nicht-Tilgung F1=Tilgung F2=Mit oder ohne Tilgung
Umlaut bei Steigerung: G0=Kein-Umlaut G1=Umlaut G2=Mit oder ohne Umlaut

|A ,B ,C ,D ,E ,F ,G ,H ,I ,J ,K ,L, OLIFC | Beispiel
A0,B0,C0,D0,E0,F0,G0,H0,I0,J0,K0,L0, 90 | “klein“
A0,B0,C0,D0,E0,F2,G0,H0,I0,J0,K0,L0, 96 | “sicher“
A0,B0,C0,D0,E0,F0,G1,H0,I0,J0,K0,L0,132 | “arm“
A0,B0,C0,D0,E1,F0,G0,H0,I0,J0,K0,L0,135 | “dunkel“
A0,B0,C0,D0,E0,F0,G2,H0,I0,J0,K0,L0,422 | “schmal“
A0,B0,C0,D3,E0,F0,G0,H0,I0,J0,K0,L0,446 | “gut“
...

Einzelne Restriktionen: Linguistisch motiviert ▸▸▸
Inhalt der Datei "infl/adjective_rules.xfst"

! Rein linguistische Restriktion
! Kein Genus in Plural und bei unspezifiziertem Numerus

define AdjectiveGendRestr [
   "&gend"
   =>
     "&numb" "=sg" _ ["=masc"|"=fem"|"=neut"]
   , "&numb" "=pl" _ "=*"
   , "&numb" "=*"  _ "=*"
   , "&numb" "=--" _ "=--"
];

Einzelne Restriktionen: Technisch motiviert

! Synchronisation von Archimorphem und Morphosyntax

define AdjectiveCOMPRestr [
 "<COMP/>"
 =>
 _ [$. ["&degr" "=comp"]]
];

define AdjectivePOSRestr [
 "<POS/>"
 =>
 _ [$. ["&degr" ["=pos"|"=*"|"=--"]]]
];

Einzelne Restriktionen: OLIF motiviert

! OLIF-Klassen, welche bestimmte Steigerungsformen nicht zulassen

define  AdjectiveDegrRestr [
   "&degr"
   =>
     .#. [$. AdjectiveMakroC0] _ ["=pos"|"=comp"|"=sup"]
   , .#. [$. AdjectiveMakroC1] _ ["=pos"]
!  , .#. [$. AdjectiveMakroC2] _ ["=comp"|"=sup"] ! Noch keine OLIF-Klassen          (Stoffadjektive "golden")
!  , .#. [$. AdjectiveMakroC3] _ ["=pos"|"=sup"] ! Noch keine OLIF-Klassen          (unter, unterst, kein unterer)
];

Hinweis

Makros sind aus der linguistischen Beschreibung automatisch erzeugte Vereinigungen von Klassenkodes, welche die Anwendung der Restriktion steuern.

Kombination von Restriktionen

Restriktionen sind Sprachen .
Die Anwendung mehrerer Restriktionen wird durch die Schnittmenge von Sprachen implementiert.
Die lexikalische Grammatik stellt ebenfalls eine Beschränkung dar.

define AdjectiveRestr [AdjectiveProtoParadigm & AdjectiveGendRestr];
define AdjectiveRestr [AdjectiveRestr & AdjectiveInflRestr];
define AdjectiveRestr [AdjectiveRestr & AdjectiveGendRestr];
define AdjectiveRestr [AdjectiveRestr & AdjectiveDegrRestr];
define AdjectiveRestr [AdjectiveRestr & AdjectivePOSRestr];
...

Phonologische Regeln

! E-Tilgung in Schluss-el beim Stamm in attributivem Positiv und Komparativ:
! Beispiel: dunk_le Sache dunk_ler Tag

define AdjectiveRuleE1 [
 e -> 0
 ||
 [$. AdjectiveMakroE1] _ l "<DEGR/>" ["<COMP/>"|"<POS/>"] [$. ["&use" "=attr"]]
];

! Optionaler Umlaut bei Steigerung
! Beispiel: gesund, gesunder, am gesundesten, ges_ü_nder, am ges_ü_ndesten
define AdjectiveRuleG2 [
 a u (@->) ä u, a (@->) ä, o (@->) ö, u (@->) ü
 ||
 [$. AdjectiveMakroG2] _ [~ $ [a|o|u]] "<DEGR/>" ["<COMP/>"|""]
];

Regeln für Suppletiv-Formen
Die Realisierung der Suppletiv-Formen lässt sich dank der wenigen Lemmata und der geringen Formvarianz über Ersetzungsregeln machen.

!Suppletiva
define AdjectiveRuleD1 [
 [ {hoch} -> {hoh} || [$. AdjectiveMakroD1] _ "<DEGR/>" "<POS/>"
 [$. ["&use" "=attr"]] ]
 .o. [ {hoch} -> {höh} || [$. AdjectiveMakroD1] _ "<DEGR/>" "<COMP/>" ]
 .o. [ {hoch} -> {höch} || [$. AdjectiveMakroD1] _ "<DEGR/>" "" ]
];

define AdjectiveRuleD4 [
 [ {viel} -> {mehr} || [$. AdjectiveMakroD4] _ "<DEGR/>" "<COMP/>" ]
 .o. [ {viel} -> {mei} || [$. AdjectiveMakroD4] _ "<DEGR/>" "" ]
];

define AdjectiveRuleD5 [
 [ {groß} -> {größ} || [$. AdjectiveMakroD5] _ "<DEGR/>" ["<COMP/>"|""]]
];

Weitere Regeln

! Realisierung des Archimorphems für Steigerung: Wegen der
! Restriktionen und vorgängiger Spezialbehandlung der Spezialfälle,
! kann die Ersetzung fast bedingungslos gemacht werden.

define AdjectiveDegrRule [
[ "" -> {t} || [$. AdjectiveMakroD5] _ ]
.o. [ "<COMP/>" -> {er}
, "" -> {st}
, "<POS/>" -> 0 ]
];
! Leere Standardregeln
define AdjectiveRuleA0 [?*];
define AdjectiveRuleA1 [?*];

[ Weiter ] [ Zurück ] [ Zurück (Seitenende) ] [ Seitenbeginn ] [ Überkapitel ] [ Bitte Skript-Fehler melden ]