Siebte Sitzung - Einführung in Perl

Ein Bummel durch Perl

Die Liste ein klein wenig sicherer machen

Am besten läßt sich dies in dem Unterprogramm &InitialisiereWoerter unterbringen, da wir uns dort die Datei sowieso ansehen. Dazu verwenden wir den -M-Operator, welcher die Anzahl der Tage liefert, die vergangen sind, seitdem eine Datei das letzte mal verändert wurde. Also müssen wir nur nachschauen, ob dieser Wert bei der Datei wortliste größer als sieben ist.

sub InitialisiereWoerter {
  open (WORTLISTE, "wortliste");
  if (-M WORTLISTE > 7) {
    die "Tut mir leid, aber die Wortliste ist älter als eine Woche!";
  }
  while ($Name = <WORTLISTE>) {
    chomp ($Name);
    $Wort = <WORTLISTE>;
    chomp ($Wort);
    $Woerter{$Name} = $Wort;
  }
  close (WORTLISTE);
}
    

Jemanden warnen, wenn etwas daneben geht

sub GutesWort {
  my ($IrgendeinName,$IrgendeinVersuch) = @_;
  $IrgendeinName =~ s/\W.*//;
  $IrgendeinName =~ tr/A-Z/a-z/;
  if (($IrgendeinName eq "joerg") ||
      ($IrgendeinName eq "oliver")) {
    "wahr";
  } elsif (($Woerter{$IrgendeinName} || "kokolores") eq $IrgendeinVersuch) {
    "wahr";
  } else {
    open (MAIL, "|mail joerg@linguistik.uni-erlangen.de,
oliver@linguistik.uni-erlangen.de");
    print MAIL "Schlechte Nachrichten:
$IrgendeinName hat $IrgendeinVersuch geraten\n";
    close (MAIL);
    "falsch";
  }
}
    

Mehrere Dateien in einem Verzeichnis

$ ls *.geheim
    

sub InitialisiereWoerter {
  while ($Dateiname = <*.geheim>) {
    open (WORTLISTE, $Dateiname);
    if (-M WORTLISTE < 7) {
      while ($Name = <WORTLISTE>) {
        chomp ($Name);
        $Wort = <WORTLISTE>;
        chomp ($Wort);
        $Woerter{$Name} = $Wort;
      }
    }
    close (WORTLISTE);
  }
}
    

So werden die geheimen Wörtern aus allen Dateien eingelesen, die im aktuellen Verzeichnis auf .geheim enden, wobei die Dateien, die älter sind als sieben Tage, ausgelassen werden.

Wir wissen wer Ihr seid!

@Passwort = getpwuid($<);
$Name = $Passwort[6];
$Name =~ s/,.*//;
    

Das siebte Element dieser Liste (Index 6) ist das GCOS-Feld, welches einen String enthält, der aus einer Liste von durch Komma getrennten Werten besteht, deren erster normalerweise der komplette Name des eingeloggten Benutzers ist.

Nach den ersten beiden Befehlen haben wir aber das komplette GCOS-Feld in der Variablen $Name, während der Name ganz vorne vor dem ersten Komma steht, weshalb wir den Rest mit dem dritten Befehl entfernen.

Diese Befehle werden nun an den Anfang des Skripts geschrieben.

#!/opt/perl5/bin/perl
&InitialisiereWoerter;
@Passwort = getpwuid($<);
$Name = $Passwort[6];
$Name =~ s/,.*//;
if (($Name =~ m/^joerg\b/i) ||
    ($Name =~ m/^oliver\b/i)) {
      [... Rest gelöscht ...]
    

Auflisten der geheimen Wörter

while ($Dateiname = <*.geheim>) {
  open (WORTLISTE, $Dateiname);
  if (-M WORTLISTE < 7) {
    while ($Name = <WORTLISTE>) {
      chomp ($Name);
      $Wort = <WORTLISTE>;
      chomp ($Wort);
      $Woerter{$Name} = $Wort;
### NEUE DATEN KOMMEN HIERHER
    }
  }
  close (WORTLISTE);
}
    

Dieses Format für die Ausgabe wird folgendermaßen definiert:

format STDOUT =
@<<<<<<<<<<<<<<<<<<<< | @<<<<<<<<<< | @<<<<<<<<<<
$Dateiname, $Name, $Wort
.
    

Zusammen mit der write-Anweisung erhalten wir das folgende Skript.

#!/opt/perl5/bin/perl
while ($Dateiname = <*.geheim>) {
  open (WORTLISTE, $Dateiname);
  if (-M WORTLISTE < 7) {
    while ($Name = <WORTLISTE>) {
      chomp ($Name);
      $Wort = <WORTLISTE>;
      chomp ($Wort);
      $Woerter{$Name} = $Wort;
      write;
    }
  }
  close (WORTLISTE);
}

format STDOUT =
@<<<<<<<<<<<<<<<<<<<< | @<<<<<<<<<< | @<<<<<<<<<<
$Dateiname, $Name, $Wort
.
    

Damit das ganze noch etwas besser aussieht, bekommen die Spalten noch Überschriften mit dem Format für den Seitenanfang.

format STDOUT_TOP =
Seite @<<
$%

Dateiname             | Name        | Wort
======================|=============|============
.
    

Alte Listen leichter erkennbar machen

Also ändern wir wieder das Unterprogramm &InitialisiereWoerter:

sub InitialisiereWoerter {
  while ($Dateiname = <*.geheim>) {
    open (WORTLISTE, $Dateiname);
    if (-M WORTLISTE < 7) {
      while ($Name = <WORTLISTE>) {
        chomp ($Name);
        $Wort = <WORTLISTE>;
        chomp ($Wort);
        $Woerter{$Name} = $Wort;
      }
    } else {
      rename ($Dateiname,"$Dateiname.alt");
    }
    close (WORTLISTE);
  }
}
    

Einrichten einer Datenbank

Zunächst erscheint ein assoziativer Array eine brauchbare Datenart dafür zu sein. Wenn man zum Beispiel den Befehl

$LetzterErfolgreicherVersuch{$Name} = time;
    

dbmopen(%LetzterErfolgreicherVersuch,"LetzterVersuchDB",0666);
$LetzterErfolgreicherVersuch{$Name} = time;
dbmclose(%LetzterErfolgreicherVersuch);
    

Im zweiten Befehl sehen wir, daß wir den abgebildeten assoziativen Array genauso wie einen normalen assoziativen Array verwenden können. Immer wenn wir diesen verändern, verändern wir auch den in der Datei gespeicherten.

Mit dem dritten Befehl, werden Datei und assoziativer Array wieder voneinander getrennt.

Diese drei Befehle werden nun in das Skript eingebaut, am besten am Ende vor der Definition der Unterprogramme.

Allerdings haben wir noch keine Möglichkeit die Daten, die von unserem Skript erzeugt werden, zu untersuchen. Deshalb schreiben wir noch ein kleines Skript, das uns die Daten der Datenbank ausdruckt.

#!/opt/perl5/bin/perl
dbmopen(%LetzterErfolgreicherVersuch,"LetzterVersuchDB",0666);
foreach $Name (sort keys (%LetzterErfolgreicherVersuch)) {
  $Wann = $LetzterErfolgreicherVersuch{$Name};
  $Stunden = (time - $Wann) / 3600;
  write;
}
dbmclose(%LetzterErfolgreicherVersuch);

format STDOUT =
Benutzer @<<<<<<<<<< : letzter erfolgreicher Rateversuch war vor @<<< Stunden.
$Name, $Stunden
.
    

Zuerst erhalten wir mit der keys()-Anweisung, die einen assoziativen Array als Argument nimmt, eine Liste aller Schlüssel dieses Arrays in unbestimmter Reihenfolge. Diese Liste wird dann mit der sort-Anweisung alphabetisch sortiert. Als letztes kommt die foreach-Schleife, die eine Liste Element für Element durchläuft, wobei sie den Wert des Elements jedesmal an eine skalare Variable überweist, mit dem dann der Block abgearbeitet wird.

In dem Block wird die Variable $Wann mit der Zeit des letzten erfolgreichen Rateversuchs von $Name besetzt. Diese Zeit wird von der aktuellen Zeit (die von der Funktion time geliefert wird) abgezogen und durch 3600 geteilt, um aus der Zeit in Sekunden die Zeit in Stunden zu ermitteln, die dann an die Variable $Stunden übergeben wird. Danach wird ein Format aufgerufen und das ganze ausgegeben.